***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec. 19, 2024                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ4528P-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     1.502
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=187.2  VTO=2.39  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=7.7096e11  gamma=0.62)
Rd     d1    d2    3.914e-3    TC=3.11e-3,1.29e-5
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=33  TBV1=3.981e-4 TBV2=-2.27e-7  CJO=9.869e-10  M=0.8288  VJ=8.102)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=1.605e-11  N=1.112  RS=4e-8  EG=1.18  TT=20n IKF=53.471 tikf=7.5e-4)
Rdiode  d1  21    3.232e-3 TC=5.1e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.526e-10
.MODEL     DGD    D(cjo=1.466e-10   M=1.967   VJ=10.039)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    5.77e-10
.ENDS PJQ4528P-AU
*$
